Cellosaurus
Cellosaurus is a comprehensive knowledge resource describing cell lines used in biomedical research, including immortalized and finite cell lines, stem cell lines, and cell lines derived from vertebrates, invertebrates, and plants. Each cell line is assigned a unique accession and is annotated with curated information such as recommended names and synonyms, species of origin, tissue and cell type, disease associations, donor characteristics, genetic alterations, STR profiles, publications, and cross-references to cell banks and external databases. The RDF representation structures these data and their relationships using the Cellosaurus ontology and links them to established biological databases and ontologies, facilitating integrated search and analysis across life science RDF datasets.
Dataset specifications
| Tags |
|
| Provenance |
Original
|
| Registration |
Added by RDF portal
|
| Data provider |
- Swiss Institute of Bioinformatics
|
| Creator |
-
the CALIPHO group, Swiss Institute of BioinformaticsSwiss Institute of Bioinformatics
|
| Issued |
2026-06-25 |
| Licenses |
-
the Creative Commons Attribution 4.0 International (CC BY 4.0)
-
See https://ftp.expasy.org/databases/cellosaurus/README
|
| Version |
Release 56 |
| Download |
/download/#cellosaurus
|
| SPARQL Endpoint |
https://rdfportal.org/sib/sparql
|
Dataset statistics
- Triples
- 19464252
- Subjects
- 3269395
- Properties
- 167
- Objects
- 5909588
- Classes
- 134
SPARQL example queries
#Retrieve cell lines with their accessions and recommended names
PREFIX cello: <https://purl.expasy.org/cellosaurus/rdf/ontology/>
SELECT ?cell_line ?accession ?name
FROM <http://rdfportal.org/dataset/cellosaurus>
WHERE {
?cell_line
cello:primaryAccession ?accession ;
cello:recommendedName ?name .
}
ORDER BY ?accession
LIMIT 100
# Search cell lines by name or synonym
PREFIX cello: <https://purl.expasy.org/cellosaurus/rdf/ontology/>
SELECT DISTINCT
?cell_line
?accession
?recommended_name
?matched_name
FROM <http://rdfportal.org/dataset/cellosaurus>
WHERE {
?cell_line
cello:primaryAccession ?accession ;
cello:recommendedName ?recommended_name ;
cello:name ?matched_name .
FILTER(
CONTAINS(
LCASE(STR(?matched_name)),
LCASE("HeLa")
)
)
}
ORDER BY ?accession
LIMIT 100
# Retrieve human cancer cell lines
PREFIX cello: <https://purl.expasy.org/cellosaurus/rdf/ontology/>
SELECT DISTINCT
?cell_line
?accession
?name
FROM <http://rdfportal.org/dataset/cellosaurus>
WHERE {
?cell_line
a cello:CancerCellLine ;
cello:primaryAccession ?accession ;
cello:recommendedName ?name ;
cello:derivedFromIndividualBelongingToSpecies ?species .
?species
cello:isIdentifiedByIRI
<http://purl.obolibrary.org/obo/NCBITaxon_9606> .
}
ORDER BY ?name
LIMIT 100
# Retrieve cell lines derived from a disease or its subclasses
PREFIX cello: <https://purl.expasy.org/cellosaurus/rdf/ontology/>
PREFIX db: <https://purl.expasy.org/cellosaurus/rdf/db/>
SELECT DISTINCT
?cell_line
?accession
?cell_line_name
?disease_name
?disease_accession
WHERE {
?cell_line
cello:primaryAccession ?accession ;
cello:recommendedName ?cell_line_name ;
cello:derivedFromIndividualWithDisease ?disease .
?disease
cello:name ?disease_name ;
cello:isIdentifiedByXref ?disease_concept .
?disease_concept
cello:more_specific_than* ?target_concept ;
cello:accession ?disease_accession .
?target_concept
cello:database db:NCIt ;
cello:accession "C5105" .
}
ORDER BY ?cell_line_name
LIMIT 100
# Retrieve cell lines derived from a specific anatomical site
PREFIX cello: <https://purl.expasy.org/cellosaurus/rdf/ontology/>
SELECT DISTINCT
?cell_line
?accession
?cell_line_name
?site_name
?site_type
FROM <http://rdfportal.org/dataset/cellosaurus>
WHERE {
?cell_line
cello:primaryAccession ?accession ;
cello:recommendedName ?cell_line_name ;
cello:derivedFromSite ?site .
?site
cello:name ?site_name ;
cello:isIdentifiedByIRI
<http://purl.obolibrary.org/obo/UBERON_0001155> .
OPTIONAL {
?site cello:siteType ?site_type .
}
}
ORDER BY ?cell_line_name
LIMIT 100
# Retrieve parent and derived cell line relationships
PREFIX cello: <https://purl.expasy.org/cellosaurus/rdf/ontology/>
SELECT DISTINCT
?parent
?parent_accession
?parent_name
?child
?child_accession
?child_name
FROM <http://rdfportal.org/dataset/cellosaurus>
WHERE {
?child
cello:hasParentCellLine ?parent ;
cello:primaryAccession ?child_accession ;
cello:recommendedName ?child_name .
?parent
cello:primaryAccession ?parent_accession ;
cello:recommendedName ?parent_name .
}
ORDER BY ?parent_name ?child_name
LIMIT 100
# Retrieve cell lines with reported TP53 variants
PREFIX cello: <https://purl.expasy.org/cellosaurus/rdf/ontology/>
SELECT DISTINCT
?cell_line
?accession
?cell_line_name
?gene_name
?hgvs
?zygosity
?variation_status
FROM <http://rdfportal.org/dataset/cellosaurus>
WHERE {
?cell_line
cello:primaryAccession ?accession ;
cello:recommendedName ?cell_line_name ;
cello:hasSequenceVariationInfo ?variation_info .
?variation_info
cello:hasTarget ?variant .
OPTIONAL {
?variation_info cello:variationStatus ?variation_status .
}
?variant
a cello:GeneMutation ;
cello:ofGene ?gene ;
cello:hgvs ?hgvs .
OPTIONAL {
?variant cello:zygosity ?zygosity .
}
?gene cello:name ?gene_name .
FILTER(STR(?gene_name) = "TP53")
}
ORDER BY ?cell_line_name ?hgvs
LIMIT 100
# Retrieve CRISPR-Cas9 knockout cell lines
PREFIX cello: <https://purl.expasy.org/cellosaurus/rdf/ontology/>
SELECT DISTINCT
?cell_line
?accession
?cell_line_name
?gene_name
FROM <http://rdfportal.org/dataset/cellosaurus>
WHERE {
?cell_line
cello:primaryAccession ?accession ;
cello:recommendedName ?cell_line_name ;
cello:hasGeneKnockout ?knockout .
?knockout
cello:hasGenomeModificationMethod cello:CrisprCas9 ;
cello:ofGene ?gene .
?gene cello:name ?gene_name .
}
ORDER BY ?gene_name ?cell_line_name
LIMIT 100