Example SPARQL queries
PAConto

1) List species names and their strains names
prefix pacsch: <http://jcggdb.jp/rdf/diseases/paconto-schema#>
prefix glycan: <http://purl.jp/bio/12/glyco/glycan#>
prefix uniprot: <http://purl.uniprot.org/core/>
prefix ggdsch: <http://jcggdb.jp/rdf/diseases/ggdonto-schema#>

select distinct ?species_name ?strain_name
from <http://jcggdb.jp/rdf/diseases/paconto>
where {
 ?species_uri ggdsch:conceptType pacsch:PathogenicMicroorganisms.
 ?species_uri uniprot:scientificName ?species_name.
 OPTIONAL {?species_uri glycan:has_strain ?strain_name.}
}
order by ?species_name ?strain_name


2) List pathogen adherence molecules of infectious agents which have a name like ‘Escherichia coli’
prefix pacsch: <http://jcggdb.jp/rdf/diseases/paconto-schema#>
prefix uniprot: <http://purl.uniprot.org/core/>
prefix ggdsch: <http://jcggdb.jp/rdf/diseases/ggdonto-schema#>

select distinct ?pathogen_name
from <http://jcggdb.jp/rdf/diseases/paconto>
where {
 ?pathogen_uri ggdsch:conceptType pacsch:PathogenAdherenceMolecules.
 ?pathogen_uri uniprot:scientificName ?scientific_name.
 FILTER regex(?scientific_name,"Escherichia coli","i")
 ?pathogen_uri pacsch:pathogenAdherMolecName ?pathogen_name.
}


3) [bookmark: _GoBack]List glycan ligands of hosts with which lectins of ‘Haemophilus influenzae’ pathogen have binding interactions
prefix pacsch: <http://jcggdb.jp/rdf/diseases/paconto-schema#>
prefix glycan: <http://purl.jp/bio/12/glyco/glycan#>
prefix uniprot: <http://purl.uniprot.org/core/>
prefix ggdsch: <http://jcggdb.jp/rdf/diseases/ggdonto-schema#>

select distinct ?glycan_name ?interaction_type
from <http://jcggdb.jp/rdf/diseases/paconto>
where {
 ?pathogen_uri ggdsch:conceptType pacsch:PathogenAdherenceMolecules.
 ?pathogen_uri uniprot:scientificName ?scientific_name.
 FILTER regex(?scientific_name,"Haemophilus influenzae","i")
 ?pathogen_reference_uri a pacsch:AffinityInReference.
 ?pathogen_reference_uri glycan:has_affinity_to ?pathogen_uri.
 ?pathogen_reference_uri pacsch:describedInReference ?reference_uri.
 ?glycan_reference_uri a pacsch:InteractionInReference .
 ?glycan_reference_uri pacsch:describedInReference ?reference_uri.
 ?pathogen_uri pacsch:interactionInReference ?glycan_reference_uri .
 ?glycan_reference_uri pacsch:interactionType ?interaction_type .
 ?glycan_reference_uri pacsch:hasInteractionWith ?glycan_uri .
 ?glycan_uri a pacsch:GlycansPACDB .
 ?glycan_uri pacsch:carbohydrateLigandName ?glycan_name .
}

4) List PMID (from PubMed) for references in which described that lectin-glycan interactions play a role in Respiratory Tract Diseases
prefix pacsch: <http://jcggdb.jp/rdf/diseases/paconto-schema#>
prefix uniprot: <http://purl.uniprot.org/core/>
prefix ggdsch: <http://jcggdb.jp/rdf/diseases/ggdonto-schema#>
prefix gmsch: <http://jcggdb.jp/rdf/diseases/gmncbi-schema#>
prefix gdgsch: <http://jcggdb.jp/rdf/diseases/gdgdb-schema#>
prefix bibo: <http://purl.org/ontology/bibo/>

select distinct ?pmid
from <http://jcggdb.jp/rdf/diseases/paconto>
where {
 ?disease_uri ggdsch:conceptType pacsch:DiseasesNameAndClass.
 ?disease_uri pacsch:diseaseClass ?disease_class .
 ?disease_uri gdgsch:diseaseNames ?disease_name .
 FILTER regex(?disease_class,"Respiratory Tract Disease","i")
 ?disease_uri gmsch:causedBy ?species_uri .
 ?species_reference_uri a pacsch:OccurInOrganismInReference.
 ?species_reference_uri uniprot:organism ?species_uri .
 ?species_reference_uri pacsch:describedInReference ?reference_uri.
 ?reference_uri ggdsch:conceptType pacsch:ReferencesData.
 ?reference_uri bibo:pmid ?pmid.
}


